--iChatNotifyBT v.b01

--Created by Alan Joyce
--http://everythingdigital.org

--Requires "None" to be chosen in Bluetooth File Exchange preferences, and the destination device to be the only bluetooth device that is added to favorites.

on notify()
tell application "Address Book"
set addressList to first name of every person
if addressList contains "NEW IM" then
set notifyCard to (get people whose first name is "NEW IM")
set notifyNow to item 1 of notifyCard
else
set addEntry to (make new person)
tell addEntry
set first name to "NEW IM"
end tell
set notifyCard to (get people whose first name is "NEW IM")
set notifyNow to item 1 of notifyCard
end if
end tell

set PathName to path to desktop
tell application "Address Book"
set cardName to "NEW IM"
set myCard to vcard of people where name is "NEW IM"
set vcardinfo to myCard as string
my makeExportFile(PathName, cardName, vcardinfo)
end tell

my sendit()
end notify

on makeExportFile(PathName, cardName, vcardinfo)
try
set target_name to cardName & ".vcf"
set target_file to (PathName as text) & target_name
tell application "Finder" to make new file at PathName ¬
with properties {name:cardName & ".vcf", creator type:"adrb"}
set the open_target_file to ¬
open for access file target_file with write permission
set eof of the open_target_file to 0
write vcardinfo to the open_target_file starting at eof
close access the open_target_file
on error theErrMsg number theErrNumber
return theErrNumber
end try
end makeExportFile

on sendit()
set PathName to path to desktop
set cardName to "NEW IM"
set target_name to cardName & ".vcf"
set vcardpath to (PathName as text) & target_name
tell application "Bluetooth File Exchange"
activate
delay 3
open file vcardpath
end tell

tell application "System Events"
tell application "Bluetooth File Exchange" to activate
delay 3
keystroke (ASCII character of 13)
end tell

end sendit

tell application "iChat"
set windowList to name of every window
set windowNum to number of items in windowList
repeat
delay 1
set windowList to name of every window
set windowNumNow to number of items in windowList
if windowNumNow is greater than windowNum then
my notify()
exit repeat
end if
end repeat
end tell